91svn2revml.t #1

#!/usr/local/bin/perl -w

=head1 NAME

91svn2revml.t - testing of vcp svn i/o

=cut

use strict ;

use Carp ;
use Cwd;
use Test ;
use VCP::TestUtils ;

my $t = -d 't' ? 't/' : '' ;

my $cwd = cwd;

if ( $^O =~ /Win32/ ) {
    $cwd =~ s{\A[A-Z]:}{};
}

my $svnroot_0 = "${t}svnroot_0";
my $svnroot_1 = "${t}svnroot_1";
my $svnroot_2 = "${t}svnroot_2";
my $svnroot_3 = "${t}svnroot_3";

my $svnspec_0 = "svn:revml2svn\@file://$cwd/$svnroot_0:";
my $svnspec_1 = "svn:revml2svn\@file:///$cwd/$svnroot_1:";
my $svnspec_2 = "svn:revml2svn\@file:///$cwd/$svnroot_2:";
my $svnspec_3 = "svn:revml2svn\@file:///$cwd/$svnroot_3:";

my $deepdir = "one/two/three/four/five";

# what change number to start incremental export at
## my $first_import_1_change; # was called $incr_change

my @tests = (
##
## revml -> svn -> revml, bootstrap export
##
sub {
   my $infile  = $t . "test-svn-in-0.revml" ;
   ##
   ## Idempotency test
   ##
   ## These depend on the "test-foo-in-0.revml" files built in the makefile.
   ## See MakeMaker.PL for how those are generated.
   ##
   ## We are also testing to see if we can re-root the files under foo/...
   ##

   my $state = "${t}91svn2revml_state_A";
   rm_dir_tree $state;

   my $in  = slurp $infile ;
   my $out = get_vcp_output(
      "$svnspec_0/foo/...",
      "--repo-id=svn:test_repository",
      { revml_out_spec => [ "--db-dir=$state", "--repo-id=revml:test_repository" ] } 
   );

   s_content qw( rep_desc time svn_info user_id ), \$in, \$out ;
   s_content qw( rev_root ),                       \$in, "foo" ;

   $in =~ s{(id="|_id>)/+ignored}{$1/foo}g;
#   $in =~ s{(id="|_id>)ignored}{$1depot/foo}g;

   ok_or_diff $out, $in;
},

## Test a single file extraction from a svn repo.  This file exists in
## change 1.

sub {
   my $state = "${t}91svn2revml_state_B";
   rm_dir_tree $state;
   ok(
      get_vcp_output(
         "$svnspec_0/foo/main/add/f1",
         "--repo-id=svn:test_repository",
         { revml_out_spec => [ "--db-dir=$state", "--repo-id=revml:test_repository" ] },
      ),
      qr{<rev_root>foo/main/add</.+<name>f1<.+<rev_id>2<.+<rev_id>3<.+</revml>}s
   ) ;
},

## Test a single file extraction from a svn repo.  This file does not exist
## in change 1.
sub {
   my $state = "${t}91svn2revml_state_C";
   rm_dir_tree $state;
   ok(
      get_vcp_output(
         "$svnspec_0/foo/main/add/f2",
         "--repo-id=svn:test_repository",
         { revml_out_spec => [ "--db-dir=$state", "--repo-id=revml:test_repository" ] },
      ),
      qr{<rev_root>foo/main/add</.+<name>f2<.+<change_id>3<.+<change_id>4<.+</revml>}s
   ) ;

},
##
## svn->revml, re-rooting a dir tree 
## copies /foo/main/a/deeply/ as if it was a whole repo
## into a target dir as if it were a complete repository.             
##
sub {
   my $state = "${t}91svn2revml_state_D";
   rm_dir_tree $state;

   my $infile  = $t . "test-svn-in-0.revml" ;
   my $in  = slurp $infile ;
   my $out = get_vcp_output(
      "$svnspec_0/foo/main/a/deeply/...",
      "--repo-id=svn:test_repository",
      { revml_out_spec => [ "--db-dir=$state", "--repo-id=revml:test_repository" ] } 
   );
   
   s_content qw( rep_desc user_id time ), \$in, \$out ;
   s_content qw( rev_root ),                    \$in, "foo/main/a/deeply" ;
   rm_elts   qw( change_id svn_info ),  \$in, \$out ;

   ## Strip out all files from $in that shouldn't be there
   rm_elts    qw( rev ), qr{(?:(?!a/deeply).)*?}s, \$in ;
   
   ## Adjust the $in paths to look like the result paths.  $in is
   ## now the "expected" output.
   $in =~ s{<(name|source_name)>main/a/deeply/}{<$1>}g ;
   $in =~ s{(id="|_id>)/+ignored}{$1/foo}g;

   $in =~ s{^\s*<rev id=.[^"']*tags.*?</rev>[ \t]*\r?\n}{}msg;
       ## the tags aren't applied until change 4

   ok_or_diff $out, $in;
},

##
## revml -> svn -> revml, incremental export
##

sub {
   my $infile  = $t . "test-svn-in-1.revml" ;

   my $state = "${t}91svn2revml_state_E";
   rm_dir_tree $state;
   copy_dir_tree "${t}91svn2revml_state_A" => $state;

   # see if got the right # of files, changes
   # svn2revml will do detailed checking (the following code)
   my $in  = slurp $infile ;
   my $out = get_vcp_output(
       "$svnspec_1/foo/...",
       "--repo-id=svn:test_repository",
       "--continue",
      { revml_out_spec => [ "--db-dir=$state", "--repo-id=revml:test_repository" ] }
   );

   $in =~ s{(<rev_root>)/+ignored/*}{$1foo}g;
   s_content qw( rep_desc user_id time svn_info ), \$in, \$out ;

   $in =~ s{(id="|_id>)/+ignored}{$1/foo}g;
   
   $in =~ s{^\s*<rev id=.[^"']*tags[^'"]*\@[34]['"].*?</rev>[ \t]*\r?\n}{}msg;
       ## the tags aren't applied until change 4

   ok_or_diff $out, $in;
},


##
## svn -> revml, incremental export in bootstrap mode
##
sub {
   my $infile  = $t . "test-svn-in-1-bootstrap.revml" ;

   my $state = "${t}91svn2revml_state_F";
   rm_dir_tree $state;
   copy_dir_tree "${t}91svn2revml_state_A" => $state;

   my $in  = slurp $infile ;
   my $out = get_vcp_output(
      "$svnspec_1/foo/...",
      "--repo-id=svn:test_repository",
      "--continue",
      "--bootstrap=...",
      { revml_out_spec => [ "--db-dir=$state", "--repo-id=revml:test_repository" ] } 
   );

   $in =~ s{(<rev_root>)/+ignored/*}{$1foo}g;
   s_content  qw( rep_desc time svn_info user_id ), \$in, \$out ;

   $in =~ s{(id="|_id>)/+ignored}{$1/foo}g;

   ok_or_diff $out, $in;
},

## Check contents of t/svnroot_2
##   extract svn to revml
##   build expected from revml
##
## svn->revml, re-rooting a dir tree
##
sub {
   my $infile  = $t . "test-svn-in-0.revml" ;
   my $in = slurp $infile;
   my $out = get_vcp_output(
      "$svnspec_2/foo/...",
      "--repo-id=svn:test_repository",
   );

   $in =~ s{(<rev_root>)/+ignored/*}{$1foo}g;
   s_content  qw( rep_desc time user_id ), \$in, \$out ;
   rm_elts    qw( svn_info       ), \$in, \$out ;

   ## Adjust the $in paths to look like the result paths.  $in is
   ## now the "expected" output.
   $in =~ s{(<(?:source_)?name>)}{${1}${deepdir}/}g;
   $in =~ s{(id="|id>)/ignored}{$1/foo/${deepdir}}g;
   $in =~ s{(_id>)ignored}{$1/foo/${deepdir}}g;

   ok_or_diff $out, $in;
},

## We don't check the contents of t/svnroot_3 because that's hard and
## not incredibly necessary.

) ;

plan tests => scalar @tests ;

my $why_skip ;
$why_skip .= svn_borken ;

$why_skip ? skip( $why_skip, '' ) : $_->() for @tests ;