apply plugin: 'groovy'
 
buildscript {
    repositories {
        maven { url 'http://artifactory.bnr.perforce.com/artifactory/repos-p4oauth' }
        jcenter()
    }
    dependencies {
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:0.3'
    }
}
 
 
repositories {
    maven {
        url 'http://artifactory.bnr.perforce.com/artifactory/repos-p4oauth'
    }
    mavenLocal()
}
 
group = "com.perforce.workshop.tjuricek"
version = "0.1.1"
 
// See http://www.gradle.org/docs/current/userguide/gradle_wrapper.html
task wrapper(type: Wrapper) {
    gradleVersion = '1.11'
}
 
dependencies {
    compile gradleApi()
    compile localGroovy()
    compile("com.perforce.workshop.tjuricek:initializer:0.1.1")
}
 
apply plugin: 'maven' // Allow local installation for testing
apply plugin: 'maven-publish'
apply plugin: 'bintray'
 
// custom tasks for creating source/javadoc jars
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}
 
task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}
 
// add javadoc/source jar tasks as artifacts
artifacts {
    archives sourcesJar, javadocJar
}
 
publishing {
    publications {
        mavenStuff(MavenPublication) {
            if (plugins.hasPlugin('war')) {
                from components.web
            } else {
                from components.java
            }
 
            artifact sourcesJar {
                classifier "sources"
            }
 
            artifact javadocJar {
                classifier "javadoc"
            }
        }
    }
}
 
if (hasProperty('bintrayUser') && hasProperty('bintrayKey')) {
 
    bintray {
        user = property('bintrayUser')
        key = property('bintrayKey')
        publications = ['mavenStuff']
        pkg {
            repo = 'maven'
            name = 'initializer-gradle-plugin'
            desc = 'Seeds data in your local Perforce server via JSON definitions'
            licenses = ['BSD']
            labels = ['perforce', 'scm', 'gradle']
        }
//        dryRun = dry // whether to run this as dry-run, without deploying
    }
}