eval '(exit $?0)' && eval 'exec perl -S $0 ${1+"$@"}'
  & eval 'exec perl -S $0 $argv:q'
  if 0;
#  THE PRECEEDING STUFF EXECS perl via $PATH
# -*-Fundamental-*-

#  $Id: //guest/richard_geiger/utils/cvs2p4/bin/genmetadata#47 $
#
#  Richard Geiger
#

require 5.000;
require "timelocal.pl";

#use bytes;

sub dirname
{
  local($dir) = @_;
  $dir =~ s%^$%.%; $dir = "$dir/";
  if ($dir =~ m%^/[^/]*//*$%) { return "/"; }
  if ($dir =~ m%^.*[^/]//*[^/][^/]*//*$%)
  { $dir =~ s%^(.*[^/])//*[^/][^/]*//*$%$1%; { return $dir; } }
  return ".";
}

use Carp; # ...or flounder. (This will fail unless 'perl' is a perl5!)
$| = 1;

($Myname = $0) =~ s%^.*/%%;
$Mydir = &dirname($0);
$Here = `/bin/pwd`; chop $Here;
if ($Mydir ne ".") { chdir "$Mydir" || die "$Myname: can't chdir \"$Mydir\": $!"; }
chdir ".." || die "$Myname: can't chdir \"..\": $!";
$Mydir = `/bin/pwd`; chop $Mydir;
chdir $Here || die "$Myname: can't chdir \"$Here\": $!";

require "$Mydir/lib/util.pl";

$Usage = <<LIT;
$Myname: usage: $Myname [-prescan]
LIT


sub usage
{
  print STDERR $Usage;
  exit 1;
}


sub help
{
  print STDERR <<LIT;
$Usage
$Myname is not done yet. Be patient.
LIT
  exit 1;
}

#  Load the branch and tag exclusion lists, if any:
#
sub load_excludes
{

  if (-e "$Convdir/exclude_tags")
    {
      if (! open(EXCLTAGS, "<$Convdir/exclude_tags"))
        {
          printf STDERR "open(\"$Convdir/exclude_tags\" failed: $!\n";
          exit 1;
        }

      $ntags = 0;
      while (<EXCLTAGS>)
        {
          chomp $_;
          if (/^\s*#/ || /^\s*$/) { next; }
          $_ =~ s/^\s*//;
          $_ =~ s/\s*#.*$//;
          $Exclude_tags{$_} = 1;
          $ntags++;
        }
      close EXCLTAGS;
      print "$Myname: loaded $ntags tag exclusions.\n";
    }

  if (-e "$Convdir/exclude_branches")
    {
      if (! open(EXCLTAGS, "<$Convdir/exclude_branches"))
        {
          printf STDERR "open(\"$Convdir/exclude_branches\" failed: $!\n";
          exit 1;
        }

      $ntags = 0;
      while (<EXCLTAGS>)
        {
          chomp $_;
          if (/^\s*#/ || /^\s*$/) { next; }
          $_ =~ s/^\s*//;
          $_ =~ s/\s*#.*$//;
          $Exclude_branches{$_} = 1;
          $ntags++;
        }
      close EXCLTAGS;
      print "$Myname: loaded $ntags branch exclusions.\n";
    }
}


######
#
#  Perlstuff for parsing RCS repository files
#

#  Some globals used by these routines...
#
$Rcs_Inquote = 0;       # remembers when we're in a '@' quoted string
$Rcs_Eofatal = 1;       # die if we hit the end of the file
$Rcs_File    = "?";     # caller should set this for the error message

sub lead
{ if (defined($Myname)) { return "$Myname: "; } else { return ""; } }

my $rcsline_buf;                  # the read buffer
my $readsize = 10 * 1024 * 1024;  # read chunk size 10Mb seems good.


#  The approach we now use bypasses stdio, in order to help handle
#  large binary archive files. rcsline() knows when it's parsing
#  a delta text token, and makes use of the fact that it can toss
#  the delta text away.
#

#  readbuf() is called to refill the input buffer.

sub readbuf
{
  my $nread = sysread(RCS, $rcsline_buf, $readsize);

  if ($nread == 0)
    {
      $readbuf_eof = 1;
      if ($Rcs_Eofatal)
        {
          $m = "unexpected eof on \"$Rcs_File\".";
          printf STDERR "%s$m\n", &lead();
          exit 1;
        }
      else
        { return undef; }
    }
  return $nread;
}


# rcsline() returns the next line of text from the read buffer, except
# when parsing a delta text token; since these may be huge, we
# leverage knowing that we don't care about the content on them, and
# throw them out, always just returning "@text@". This seems to get
# acceptable performance with large binary files.
#

sub rcsline
{
  my ($in_text) = @_; # Flag says when the last token seen was "text",
                      # i.e., when we're parsing the actual delta text

  my $linesave = "";  # Used to accumulate text longer than rcsline_buf's
                      # read size. Well, in theory, at least. Should only happen
                      # if there are log messages > 10Mb!

  while (1)
    {
      # If the buffer is empty, we read:
      #
      if (! $rcsline_buf)
        { if (&readbuf() == undef) { return undef; } }

      #  ASSUMPTION: RCS will always put the '@' starting a string
      #              at the beginning of a new line... thus we'll
      #              KNOW at this point to expect a delta text.
      #
      if ($in_text && ($rcsline_buf =~ /^\@/))
        {
          $rcsline_buf =~ s/^\@//;

          # Handle the special case where the revision delta text is empty:
          #
          if ($rcsline_buf =~ /^\@[^\@]/s)
            {
              $rcsline_buf =~ s/^\@//;

              return "@@\n";
            }

          # Aha! We're in a (possibly long, binary!) string, that we
          # don't care about the value of; in a "text" token
          # value... we're just looking for the end! "Return, or bust"
          # from here!
          #
          while (1)
            {
              # Can we see the end of the string?
              #
             if ($rcsline_buf =~ /^(.*?[^\@])\@([^\@].*)$/s)
                {
                  $rcsline_buf = $2;
                  return "\@text\@\n";
                }
              elsif ($rcsline_buf =~ /[^\@]\@$/s)
                {
                  # If the last char in the buffer is an "@", we can't know if
                  # it is an escaped @ or the closing delimiter until we see the
                  # next character...
                  #
                  if (&readbuf() == undef)
                    {
                      return "\@text\@";
                    }

                  if ($rcsline_buf =~ /^\@/)
                    {
                      # we hit the seam! Eat the @ and continue...
                      $rcsline_buf =~ s/^\@//;
                    }
                  else
                    {
                      # Well I'll be! That -was- a closing string delim!
                      return "\@text\@";

		      # (We leave rcsline_buf unmolested for future processing)
                    }
                }
              else
                {
                  # We KNOW the entire remainder of the buffer is part of the string value.
                  # and can just chuck it, grabbing a new buffer'sworth.
                  #
                  if (&readbuf() == undef) { return undef; }
                }
            }
        }
      else
        { 
          my ($line, $remainder) = ($rcsline_buf =~ m/^([^\n]*\n)(.*)$/s);
          if ($line)
            {
              $rcsline_buf = $remainder;
              if ($line =~ /\r{0,1}\n$/) { $line =~ s/\r{0,1}\n$//; }
              return $linesave.$line;
            }
          else
            {
              $linesave .= $rcsline_buf;
              $rcsline_buf = "";
            }
        }
    }
}

$Rcstok_Buf = "";
$Rcstok_pushed = undef;

#  Return the next token from the RCS repository file.
#  Caller should open the file on descriptor RCS.
#  (Caller should also empty $Rcstok_Buf!)

my $lasttok;

sub rcstok
{
  my $rcsstr;
  my $m;
  my $strpart;

  if (defined($Rcstok_pushed))
    {
      my $ret = $Rcstok_pushed;
      $Rcstok_pushed = undef;

      return ($lasttok = $ret);
    }

  $Rcstok_Buf =~ s/^\s+//;

  if ($Rcstok_Buf eq "")
    {
      while (1)
        {
          $Rcstok_Buf = &rcsline($lasttok eq "text");
          if (! defined ($Rcstok_Buf)) { return undef; }
          if ($Rcstok_Buf ne "") { last; }
        }
      $Rcstok_Buf =~ s/^\s+//;
    }

  #  : ; id
  #
  #  Note: the character class for "idchar" assumes all characters
  #  are printable ascii! May break with binary RCS files.
  #  (Actually, I've now convinced myself that there is no
  #  concern here).
  #
  if ($Rcstok_Buf =~ /^(:|;|[0-9.]*[^ \t\r\n$,:;@]+)(.*)$/)
    { $Rcstok_Buf = $2; return ($lasttok = $1); }

  #  num
  #
  if ($Rcstok_Buf =~ /^([0-9][0-9.]*)(.*)$/)
    { $Rcstok_Buf = $2; return ($lasttok = $1); }

  #  string
  #
  if ($Rcstok_Buf =~ /^@(.*)$/)
    {
      $Rcstok_Buf = $1;
      $rcsstr = "";
      while (1)
        {
          if ($Rcstok_Buf eq "")
            {
              if ($lasttok ne "text") { $rcsstr .= "\n"; }
              $Rcstok_Buf = &rcsline($lasttok eq "text");
              if (! defined ($Rcstok_Buf)) { return undef; }
            }
          if ($Rcstok_Buf =~ /^(.*[^@])@([^@].*)$/)
            {
              my $tmp = $1;
              $Rcstok_Buf = $2;
              $tmp =~ s/\@\@/\@/g;
              if ($lasttok eq "text")
                { $rcsstr = "[deltatext]"; }
              else
                { $rcsstr .= $tmp; }
              return ($lasttok = $rcsstr);
            }
          if ($Rcstok_Buf =~ /^.*\@\@$/)
            {
              # check for multiple @s at the end - have to look for odd number
              $Rcstok_Buf =~ /^(.*[^@])(\@+)$/;
              my $tmp = $1;
              $Rcstok_Buf = $2;
              $tmp =~ s/\@\@/\@/g;
              if ($lasttok eq "text") { $rcsstr .= $tmp; }
              my $odd = length($Rcstok_Buf) % 2;
              if ($odd)
                { $Rcstok_Buf = substr($Rcstok_Buf, 1); }
              $Rcstok_Buf =~ s/\@\@/\@/g;
              if ($lasttok eq "text") 
                { $rcsstr = "[deltatext]"; }
              else
                { $rcsstr .= $Rcstok_Buf; }
              $Rcstok_Buf = "";
              if ($odd)
                { return ($lasttok = $rcsstr); }
            }
          if ($Rcstok_Buf =~ /^(.*)\@$/)
            {
              my $tmp = $1;
              $Rcstok_Buf = "";
              $tmp =~ s/\@\@/\@/g;
              if ($lasttok eq "text") 
                { $rcsstr = "[deltatext]"; }
              else
                { $rcsstr .= $tmp; }
              return ($lasttok = $rcsstr);
            }
          if ($Rcstok_Buf =~ /^\@([^@].*)$/)
            {
              $Rcstok_Buf = $1;
              if ($lasttok eq "text") { $rcsstr = "[deltatext]"; }
              return ($lasttok = $rcsstr);
            }
          if ($Rcstok_Buf =~ /^\@$/)
            {
              $Rcstok_Buf = "";
              if ($lasttok eq "text") { $rcsstr = "[deltatext]"; }
              return ($lasttok = $rcsstr);
            }
          $Rcstok_Buf =~ s/\@\@/\@/g;
          if ($lasttok eq "text")
            { $rcsstr = "[deltatext]"; }
          else
            { $rcsstr .= $Rcstok_Buf; }
 
          $Rcstok_Buf = "";
        }
    }

  $m = "rcstok(): internal error: \$Rcstok_Buf <$Rcstok_Buf>";
  printf STDERR "%s$m\n", &lead();
  exit 1;
}

sub dirname
{
  my ($dir) = @_;

  $dir =~ s%^$%.%; $dir = "$dir/";
  if ($dir =~ m%^/[^/]*//*$%) { return "/"; }
  if ($dir =~ m%^.*[^/]//*[^/][^/]*//*$%)
    { $dir =~ s%^(.*[^/])//*[^/][^/]*//*$%$1%; { return $dir; } }
  return ".";
}


sub skip_to_rcstok
{
  my ($this) = @_;
  my $tok;
  while (($tok = &rcstok()) ne $this) { };
}


sub skip_to_deltas
{
  my $tok;

  # Called after we encounter ";" for symbols. We must now skip:
  #
  #   locks      {id : num}*;  {strict  ;}
  #   { comment  {string}; }
  #   { expand   {string}; }
  #   { newphrase }*

  while (1)
    {
      my $fatalsave = $Rcs_eofatal;

      $tok = &rcstok();

      if ($tok eq "expand")
        {
          $RCS_expand = &rcstok();
          if (&rcstok() ne ";")
            { die "$Myname: skip_to_deltas(): expected ';' after expand."; }
          next;
        }
      if ($tok =~ /^[0-9]/) { $Rcstok_pushed = $tok; last; }
      while (1)
        {
          # Turning this off here because it looks like cvs problems can create
          # delta-less ,v files; this allows us to handle this.
          #
          $Rcs_Eofatal = 0;
          $tok = &rcstok();
          $Rcs_Eofatal = $fatalsave;
          if (! defined($tok)) { return undef; }

          if ($tok eq ";") { last; }
        }
    }
  return 1;
}


sub sdump
{
  my ($s) = $1;

  my @s = split(//, $s);

  my $ret = "";
  foreach my $c (@s)
    { $ret .= sprintf(" %02x", ord($c)); }
  return $ret;
}


sub test_rcstoks
{
  my $tok;

  print "open $ARGV[1]\n";

  open(RCS, "<$ARGV[1]") || die;
  $Rcstok_Buf = "";

  $Rcs_Eofatal = 0;
  while (defined($tok = &rcstok))
    { print "<$tok>\n"; }

  exit 0;
}


sub setrevs
{
  my($d_rev, $d_next, $d_branches, $d_date, $d_author, $d_state) = @_;
  my($b_rev);

  $RCS_Revs{$d_rev} = "$d_next:$d_branches";
  $d_date = "19$d_date" if length(( split( /\./, $d_date ))[0]) < 4;
  $RCS_Dates{$d_rev} = "$d_date";
  $RCS_Authors{$d_rev} = "$d_author";
  $RCS_States{$d_rev} = "$d_state";

  if ($d_rev =~ /^1\.1\.1(\.[0-9]+)?$/)
    {
      # We have a "vendor" branch - spoof a branch tag for it.
      #
      my $import_branch = "import";
      if ($PureRCS) { $import_branch = "1.1.1"; }

      $Brtags{$import_branch} = 1;              
      $RCS_Branchtags{$import_branch} = "1.1.0.1";
      $RCS_Tags{$import_branch} = "1.1.0.1";
    }

  if ($d_rev =~ /^[0-9]+\.[0-9]+$/)
    {
      $RCS_Prevs{$d_rev} = $d_next;
      if ($d_next) { $RCS_Nexts{$d_next} = $d_rev; }
    }
  else
    {
      if ($d_next) { $RCS_Prevs{$d_next} = $d_rev; }
      $RCS_Nexts{$d_rev} = $d_next;
    }
  foreach $b_rev (split(/ /, $d_branches))
    { $RCS_Prevs{$b_rev} = $d_rev; }
}


#  initialize RCS_Tags, RCS_Revs, (etc.) from an RCS ,v file.
#
sub set_RCS_revs
{
  my ($path, $do_texts) = @_;
  my $repdir;
  my $repfile;
  my $tag;
  my $rev;
  my $tok;
  my ($d_havedelta, $d_branches, $d_next, $d_rev);
  my ($ext, $format);
  my $rcspath;
  my $msg;
  my $admaci = 0;
  my $File;

  undef $RCS_File;
  undef $RCS_Valid;
  undef $RCS_expand;
  undef $RCS_exec;
  undef %RCS_Tags;		# both plain and branch (and special "head")
  undef %RCS_Branchtags;        # branch, only
  undef %RCS_rev_brtags;        # inverse of the above - keyed by branch tag value
  undef %RCS_Revs;
  undef %RCS_States;
  undef %RCS_Authors;
  undef %RCS_Dates;
  undef %RCS_Prevs;
  undef %RCS_Nexts;
  undef $RCS_Branch;
  undef %RCS_Texts;
  undef $RCS_import_is_main;

  undef $rcsline_buf;

  ($Rcs_File = $path) =~ s%^.*/%%;
  ($File = $Rcs_File) =~ s/,v$//;

  $repdir = &dirname($path);

  if (-r "$repdir/.adamci,v") { $adamci = 1; }

  $repfile = $path;

  $rcspath = "<$repfile";

  if (! open(RCS, $rcspath))
    {
      printf STDERR "%scan't open \"$rcspath\": $!\n", &lead();
      return 0;
    }
  $RCS_File = $rcspath;

  if (-x $repfile) { $RCS_exec = "x"; }

  $Rcstok_Buf = "";

  &skip_to_rcstok("head");

  $RCS_Tags{"head"} = &rcstok();

  $tok = &rcstok(); $tok = &rcstok();

  if ($tok eq "branch") { $RCS_Branch = &rcstok(); }

  if ($RCS_Branch eq "1.1.1") { $RCS_import_is_main = 1; }

  &skip_to_rcstok("symbols");

  while (1)
    {
      $tok = &rcstok();
      if ($tok eq ";") { last; }
      $tag = $tok; &rcstok(); $rev = &rcstok();

      if (($cnt = $rev =~ tr/\./\./) % 2 == 0)
        {
          if ($rev ne "1.1.1") # 'cause we call it "import"!
            {
              # Handle "RCS" branch tags:
              #
              my @nums = split(/\./, $rev);

              splice @nums, $#nums, 0, (0);
              $rev = join(".", @nums);
            }
        }

      if ((! $PureRCS) && $rev =~ /\.0\.[0-9]+$/)
        {
          if (! $adamci)
            {
              $RCS_Tags{$tag} = $rev;
              $RCS_Branchtags{$tag} = $rev;
              if (defined($BRANCH_FLASH)) { $tag =~ s/$BRANCH_FLASH$//; }
              $Brtags{$tag} = 1;              
              if ($RCS_rev_brtags{$rev})
                { print "WARNING: file: $RCS_File: dup CVS branch tags on rev <$rev> (tag <$tag>)(ignored)\n"; }
              else
                { $RCS_rev_brtags{$rev} = $tag; }
            }
        }
      elsif (($cnt = $rev =~ tr/\./\./) % 2 == 1)
        {
          $RCS_Tags{$tag} = $rev;
          my $rcspath;
          ($rcspath = $repfile) =~ s/,v$//;

          if ($IMPORTTAGSPOOF && $rev eq "1.1.1.1") { $rev = "1.1"; }

          if (! defined($Exclude_tags{$tag}))
            {
              print LABELS "$tag$S$rcspath$S$rev\n";

#              if (! defined($RCS_Revtags{$tag}))
#                { $RCS_Revtags{$tag} = [ ] ; }
#              if ($IMPORTTAGSPOOF && $rev eq "1.1.1.1") { $rev = "1.1"; }
#              push(@{$RCS_Revtags{$tag}}, "$reppath/$rev");

              # don't want to wipe out previously observed one, as it might
              # already have found the "real" mapping!
              #
              if (! defined($Tags{$tag})) { $Tags{$tag}  = ""; } 
            }
        }
    }

  # OK, we get here having seen every tag in the file. See whether,
  # for any of the tags we saw in this file, we can determine the
  # branch for that tag, and remember the mapping globally.

  try_tag: foreach my $tag (sort(keys(%RCS_Tags)))
    {
      # Only want to consider rev tags:
      #
      if (defined($RCS_Branchtags{$tag})) { next; }

      my $tagrev = $RCS_Tags{$tag};

      # Branch 1.1.1 is specially known as "import":
      #
      if ($tagrev =~ /^1\.1\.1\.(\d+)$/)
        {
          $Tags{$tag} = "import";
          $Tagfiles{$tag} = $RCS_File;
          next try_tag;
        }

      # So: do any of the known branch tags in this file select the
      # tagged revision?
      #
      my $tagrev_brnum;
      ($tagrev_brnum = $tagrev) =~ s/\.\d+$//;

      # Figure out which branch this revision is present in by virtue
      # of *other* than being the branch point:
      #
      my $sel_br;
      if ($tagrev_brnum =~ /^\d+$/)
        { $sel_br = "main"; }
      else
        {
          my ($sel_brbase, $sel_brnum) = ($tagrev_brnum =~ /^(.*)\.(\d+)$/);
          my $sel_brrev = "$sel_brbase.0.$sel_brnum";
          if ($RCS_rev_brtags{$sel_brrev}) { $sel_br = $RCS_rev_brtags{$sel_brrev} }
        }

      if (! $sel_br)
        {
          # We can't make a determination :-(
          # (Might want to track these TBD; shouldn't happen much if at all, right?
          # One could argue that this would represent CVS "corruption" - a tagless branch!
          #
          next try_tag;
        }

      # OK, so now, is our revision also selected by virtue of being a branch point?
      # (If so, it's ambiguous for this file)
      #
      my $try_limit = 5;
      my $g = 0;
      my $try_tag;

      for ($i = 1; $g <= $try_limit; $i++)
        {
          my $try_rev = "$RCS_Tags{$tag}.0.$i";

          if ($RCS_rev_brtags{$try_rev}) { next try_tag; }

          # If we see that the branch number exists, we should keep looking.
          # We want to give up when we either A) find the branch or
          # B) have found $try_limit unused branch bumbers in a row.
          # Since CVS is supposed to dole them out sequentially, this
          # -should- be sufficient to decide that there are no more.
          # This should be better for efficiency, compared to checking
          # every key in $RCS_rev_brtags.
          #
          if (defined($RCS_rev_brtags{$try_tag})) { $g = 0; next; }
          $g++;
        }

      # so... if we get here, in theory, the heuristic was applicable!
      # $sel_br has the presumptive mapping.

      # Now, make sure we didn't get a different answer than from some previous
      # file:

      if ($Tags{$tag} && ($Tags{$tag} ne $sel_br))
        {
          if ($Tags{$tag} eq "UNMAPPED") { next try_tag; }
          # Probably want to log and proceed... TBD
          print "\nERROR: file: $RCS_File: conflicting branch determination for tag \"$tag\": ".
                "  <$Tags{$tag}> vs <$sel_br>; ";
          print "  (previous file:\"$Tagfiles{$tag}\").\n";

          #  The idea is to not trust the result for this tag!
          #
          $Tags{$tag} = "UNMAPPED";
        }
      else
        {
          # Ahhhhhhhhhh that feels so good.... 
          #
          $Tags{$tag} = $sel_br;

          # And remember where we saw it!:
          #
          $Tagfiles{$tag} = $RCS_File;
        }
    }
      
  if ($Prescan) { return 1; }

  if ($adamci)
    {
      undef %metadata;
      eval `$CO -q -p $repdir/.adamci,v`; # TBD: Optimize this to only reread if new dir?

      foreach my $p (keys(%{$metadata{'context_rules'}}))
        {
          my $k;
          ($k) = keys( %{${${$metadata{'context_rules'}}{$p}}{$File}}  );

          if (defined($k) && $k ne "TBB")
            {
              my $rev = ${${${${$metadata{'context_rules'}}{$p}}{$File}}{$k}}[1];
              $rev =~ s/^(.*\.\d+)\.(\d+)$/$1.0.$2/;
              $RCS_Tags{$p} = $rev;
              $RCS_Branchtags{$p} = $rev;
            }
        }
    }

  if (&skip_to_deltas() == undef) { return undef; }

  $d_rev = ""; $d_havedelta = 0; $d_branches = ""; $d_next = "";

  while (1)
    {
      $tok = &rcstok();
      if ($tok =~ /^[0-9.]+$/)
        {
          if ($d_havedelta)
            { &setrevs($d_rev, $d_next, $d_branches, $d_date, $d_author, $d_state); }
          $d_rev = $tok; $d_havedelta = 1; $d_branches = ""; $d_next = "";
        }
      elsif ($tok eq "branches")
        {
          while (1)
            {
              if (($tok = &rcstok()) eq ";") { last; }

              if ($PureRCS)
                {
                  my ($l, $b, $r) = ($tok =~ /(.*)\.(\d+)\.(\d+)$/);
                  my $tag = "$l.$b";
                  $RCS_Branchtags{$tag} = $rev;
                }

              if ($d_branches ne "") { $d_branches .= " "; }
              $d_branches .= $tok;
            }
        }
      elsif ($tok eq "date")   { $tok = &rcstok(); if ($tok ne ";") { $d_date = $tok; &rcstok(); } }
      elsif ($tok eq "author") { $tok = &rcstok(); if ($tok ne ";") { $d_author = $tok; &rcstok(); } }
      elsif ($tok eq "state")  { $tok = &rcstok(); if ($tok ne ";") { $d_state = $tok; &rcstok(); } }
      elsif ($tok eq "next")   { $tok = &rcstok(); if ($tok ne ";") { $d_next = $tok; &rcstok(); } }

    # Note: "format" and "ext" seem to be extentions used by MKS
    # Source Integrity. They don't show up in my rcsfile(5) man
    # page!

      elsif ($tok eq "format") { $tok = &rcstok(); if ($tok ne ";") { $format = $tok; &rcstok(); } }
      elsif ($tok eq "ext")    { $tok = &rcstok(); $ext = $tok; }
      elsif ($tok eq "desc") { last; }
      else { &skip_to_rcstok(";"); }
    }

  if ($d_havedelta)
    { &setrevs($d_rev, $d_next, $d_branches, $d_date, $d_author, $d_state); }

  if (! defined($do_texts)) { close RCS; $RCS_Valid = 1; return 1; }

  $Rcs_Eofatal = 0;
  while (1)
    {
      $tok = &rcstok();
      if (! defined($tok)) { last; }
      if ($tok =~ /[0-9.]+/)
        { $d_rev = $tok; }
      elsif ($tok eq "text")
        {
          $msg = &rcstok();
          if ($msg eq "") { $RCS_Texts{$d_rev} = 0; } else { $RCS_Texts{$d_rev} = 1; }
        }
      elsif ($tok eq "log")
        { $log = &rcstok(); $RCS_Logs{$d_rev} = $log; }
    }
  $Rcs_Eofatal = 1;

  close RCS;
  $RCS_Valid = 1;
  return 1;
}


sub rcs_tip
{
  my ($rev) = @_;
  my $next;

  #  Find the tip of the branch...
  #
  while (1)
    {
      if (! defined($RCS_Revs{$rev}))
        { return "???"; }
      ($next) = split(/:/, $RCS_Revs{$rev});
      if ($next eq "") { return $rev; }
      $rev = $next;
    }
}


#  given a "CVS line spec" (revision #, "head", or a tag)
#
sub rev_on_line
{
  my($line) = @_;

  if ($line eq $TRUNKLINE)
    { $line = "head"; }
#  else
#    { $line = "${line}_BRANCH"; }

  if (defined($RCS_Tags{$line})) { $line = $RCS_Tags{$line}; }
  elsif ($line !~ /^[0-9.]+$/) { return "none"; }
  if ($line =~ /\.0\.([0-9]+)$/)
    {
      # It's a CVS branch revision number... demunge it:
      #
      $line =~ s/\.0(\.[0-9]+)$/$1/;

      #  OK, see whether the branch actually exists:
      #  (We have an assumption here that first rev is always ".1")
      #
      $line = "$line.1";
      if (! defined($RCS_Revs{$line}))
        {
          # Nope, so fall back to the root, which we know to be an
          # existing revision...

          $line =~ s/\.[0-9]+\.[0-9]+$//;
          return $line;
        }

      # Yep, the branch exists; so it *is* a branch; so, we go out to
      # the tip. (Right?)
      #
      return &rcs_tip($line);
    }

  #  OK, do we have an RCS branch or an RCS revision number?  (count
  #  the dots)
  #
  if (($line =~ tr/\././) % 2)
    {
      #  An odd number of dots... it's a revision number
      #
      if (defined($RCS_Revs{$line})) { return $line; }

      return "none"; # Or should we assert?
    }
  else
    {
      #  An even number of dots... it's a branch number
      #  (We have an assumption here that first rev is always ".1")
      #
      return &rcs_tip("$line.1");
    }
}


#  Is rev "$this" < rev "$that"?
#  Note: "" is considered infinitely high
#        revs must be of the same order (I.e., same # of "."s)
#
sub rev_lt
{
  my($this, $that) = @_;
  my(@this, @that);

  if (! $that) { return 1; }

  @this = split(/\./, $this);
  @that = split(/\./, $that);

  while (1)
    {
      $this_n = shift(@this);
      $that_n = shift(@that);

      if ($this_n < $that_n) { return 1; }
      if ($this_n > $that_n) { return 0; }
      if ($#this < 0) { return 0; }
    }
}


#  Note: "" is considered infinitely high
#
sub linerev_gt
{
  my($this, $that) = @_;
  my $ret;

  if (! $that)
    { $ret =  1; }
  else
    {
      my $thisord, $thatord;
      $thisord = ($this =~ tr/\././);
      $thatord = ($that =~ tr/\././);
      if ($thisord < $thatord)
        { $ret = 1; }
      elsif ($thisord > $thatord)
        { $ret = 0; }
      else
        { $ret = &rev_lt($that, $this); }
    }
  return $ret;
}


# Maximum size for a log message we'll keep.
# Messages beyond this get truncated, to accomodate a limitation
# on the key/value pair size in ndbm. That's life.
#
$MAXSZ = 256*3;

#  Generate the metadata for a single file
#
sub dofile
{
  local($dir, $file) = @_;

  if ($file !~ /,v$/) { return; }
  if ($IGNOREFILES && $file =~ /$IGNOREFILES/) { return; }

  if ($file =~ /[\000-\037\177-\377]/)
    {
      print "$Myname: RCS filename with non-printable characters (skipped): ";
      $l = length($file);
      for ($i = 0; $i <= $l; $i++)
        {
          $c = substr($file, $i, 1);
          if ($c =~ /[\000-\037\177-\377]/)
            { printf "\\%03o", ord($c); }
          else
            { print "$c"; }
        }
      print "\n";
      return;
    }

  elsif ($file =~ /\.\.\./)
    {
      print "$Myname: RCS filename with illegal Perforce characters (skipped): $file\n";
      return;
    }

#if ($file ne "rm.c,v") { return; }

  undef %RCS_lines;
  undef %RCS_Branches;
  undef $Firstusedrev;

  print "$dir/$file";

  # This parses the RCS information from the ,v file, filling
  # in various data structures that we use, below.
  #
  if (&set_RCS_revs("$dir/$file", 0) == undef) { print " (empty)\n"; return; } # empty ,v

  # What RCS keyword expansion options are in effect?
  # (We use this to detect binary files)
  #
  $options = "${RCS_expand}$RCS_exec";
  if (! $options) { $options = "-"; }

  @path = split(/\//, "$dir/$file");
  $file = pop(@path);
  $file =~ s/,v$//;
  if ($path[$#path] eq "Attic") { pop @path; }
  $na_dir = join("/", @path);
  $path = sprintf("%s%s%s", $dir, $dir ? "/" : "", $file);
  $na_path = sprintf("%s%s%s", $na_dir, $na_dir ? "/" : "", $file);

  print " -> $path\n";

  # The "defined($Filesseen{$path})" saves lots of stat()s!
  #
  if (defined($Filesseen{$path}))
    {
      my @p = split(/\//, "$na_path");

      splice(@p, $#p, 0, "Attic");
      my $a_path = join("/", @p);

      #  Users have seen this, which previous caused mysterious death
      #  in the sort phase... let's be a little more informative:
      #
      if (-f "$na_path,v" && -f "$a_path,v")
        { die "assert: CVS repository has both\n  $na_path\nand\n  $a_path"; }
      else
        { die "assert: dofile(): duplicate path: $na_path"; }

    }

  $Filesseen{$path} = 1;

  if ($Prescan) { return; }

  # For all of the branches we see, store the tip revision in
  # $HAVELINES{$line}; this is also where we weed out
  # codelines we are not interested in.
  #
  foreach $line ((keys %RCS_Branchtags), $TRUNKLINE)
    {
      # Note: lines added to the exclude_branches file should
      # give the actual, complete branch tag name, not the 
      # "de-flashed" (if any) rendition.
      #
      if (defined($Exclude_branches{$line})) { next; }
      $no_flash_line = $line;
      if (defined($BRANCH_FLASH)) { $no_flash_line =~ s/$BRANCH_FLASH$//; }
      if ($WANTLINES && ! (defined($WANTLINES{$no_flash_line}))) { next; }
      if (($tiprev = &rev_on_line($line)) eq "none") { next; }
      $HAVELINES{$line} = $tiprev;
    }

  #  Now we go through each line, to build a list of the RCS revs that
  #  need to be exported into the metadata stream.
  #
  while (1) # We have more lines to deal with...
    {
      (@k) = (keys %HAVELINES);
      if ($#k < 0) { last; }
      my $theline;

      #  Choose the highest numbered line of the lowest "order" for
      #  the next one to export... this will always pickup lines on
      #  branches nearer the trunk first, so the subsequent branches
      #  will have a place to branch from!
      #
      foreach $k (@k)
        {
          if ($k eq $TRUNKLINE) { $theline = $k; last; }

          #  if both lines select the *same* revision...
          #
          if ($HAVELINES{$k} eq $HAVELINES{$theline})
            {
              # ...take the one with the lower branch tag order first
              #
              if (&linerev_gt($RCS_Branchtags{$k}, $RCS_Branchtags{$theline}))
                { $theline = $k; next; }
            }

          if (&linerev_gt($HAVELINES{$k}, $HAVELINES{$theline}))
            { $theline = $k; }
        }

      $rev = $tiprev = &rev_on_line($theline);

      $t = $theline;
      if (defined($BRANCH_FLASH))
        { $t =~ s/$BRANCH_FLASH$//; }

      #  This is where we build the list of codelines we've encountered.
      #
      $All_lines{$t} = 1;

      if (  (defined($RCS_lines{$rev})) &&
            ($theline ne $TRUNKLINE) &&
            (($rev =~ tr/\././) < ($RCS_Branchtags{$theline} =~ tr/\././)))
        {
          if ($RCS_Branches{$rev}) { $RCS_Branches{$rev} .= ":"; }
          $RCS_Branches{$rev} .= $t;
        }
      else
        {
          while ($rev && ! defined($RCS_lines{$rev}))
            {
              $RCS_lines{$rev} = $theline;
              $rev = $RCS_Prevs{$rev};
            }
          if ($rev)
            {
              if ($RCS_Branches{$rev}) { $RCS_Branches{$rev} .= ":"; }
              $RCS_Branches{$rev} .= $t;
            }
        }

      # We test for "if $rev" here cause it may have gone null if the while loop
      # above ran off the end...
      #
      if ($rev && (($rev =~ tr/\././) == 1) && &rev_lt($rev, $Firstusedrev))
        { $Firstusedrev = $rev }

      delete $HAVELINES{$theline};
    }

  #  OK, we have the set of revisions to export - write them to the
  #  metadata stream.
  #
  foreach $rev (keys %RCS_Revs)
    {
      $revkey = "$path/$rev";

      $state = $RCS_States{$rev};
      $author = $RCS_Authors{$rev};
      $date = $RCS_Dates{$rev};
      my ($yr, $mo, $da, $hr, $mi, $se) = split (/\./, $date);
      $date = timegm($se,$mi,$hr,$da,$mo - 1,$yr);
      $line = $RCS_lines{$rev};
      if (defined($BRANCH_FLASH)) { $line =~ s/$BRANCH_FLASH$//; }
      $branches = $RCS_Branches{$rev};

      #  Detect revisions before the first branch point, and
      #  omit them if we're not doing ALLTHEWAYBACK.
      #
      if ( (! $ALLTHEWAYBACK)
           && ($line eq $TRUNKLINE)
           && ($rev ne $RCS_Tags{"head"})
           && $Firstusedrev
           && &rev_lt($rev, $Firstusedrev))
             { next; }

      if (! $line) { next; }
      if (! $branches) { $branches = "-"; }

      if ((! $ALLTHEWAYBACK) && $rev eq $Firstusedrev)
        { $prevrev = "-"; }
      elsif ($RCS_Prevs{$rev})
        { $prevrev = $RCS_Prevs{$rev}; }
      else
        { $prevrev = "-"; }

      $All_lines{$line} = 1;

      if ($RCS_import_is_main)
        {
          if ($line eq "import") { $line = $TRUNKLINE; }

          my @btmp = split(/ /, $branches);
          my $newb = "";
          foreach my $b (@btmp)
            {
              if ($b eq "import") { next; }
              if ($newb) { $newb .= " "; }
              $newb .= $b;
            }
          $branches = $newb;
        }

      print METATMP "$revkey$S$date$S$author$S$state$S$line$S$branches$S$prevrev$S$options\n";

      #  MAXSZ derives from a ndbm limitation on the size of a key/entry pair.
      #  at (256*3) it allows for a $revkey up to 250 chars or so.
      #
      $logmsg = substr($RCS_Logs{$rev}, 0, $MAXSZ);
      if ($logmsg !~ /\n$/) { $logmsg .= "\n"; }

      if (length($logmsg)+length($revkey) > 1010)
        { print "$Myname: revkey + log too long for <$revkey>\n"; exit 1; }

      $MSGS{$revkey} = $logmsg;
    }
}

# option switch variables get defaults here...

$Convdir = "";

$Boolopt = 0;
$Valopt = 0;
$Prescan = 0;

while ($#ARGV >= 0)
  {
    if ($ARGV[0] eq "-testtoks")   { &test_rcstoks; }
    if ($ARGV[0] eq "-prescan")    { $Prescan = 1; shift; next; }
    elsif ($ARGV[0] eq "-valopt")
      {
        shift; if ($ARGV[0] < 0) { &usage; }
        $Valopt = $ARGV[0]; shift; next;
      }
    elsif ($ARGV[0] eq "-help")
      { &help; }
    elsif ($ARGV[0] =~ /^-/) { &usage; }
    if ($Args ne "") { $Args .= " "; }
    push(@Args, $ARGV[0]);
    shift;
  }

if ($#Args ne 0) { &usage; }

$Convdir = $Args[0];

$Metatmp   = "$Convdir/metatmp";
$Metadata  = "$Convdir/metadata";
$Labels    = "$Convdir/labels";
$Tags	   = "$Convdir/tags";
$Tagfiles  = "$Convdir/tagfiles";
$Brtags	   = "$Convdir/brtags";
$Logmsgs   = "$Convdir/logmsgs";
$Filesseen = "$Convdir/filesseen";

$Changes   = "$Convdir/changes";
$Revmap    = "$Convdir/revmap";
$Clientdir = "$Convdir/p4";

require "$Convdir/config";

&load_excludes();

#  (Handle either f or f.db or f.pag, f,dir style dbs):
#
if (&s("/bin/rm -rf $Logmsgs $Logmsgs.db $Logmsgs.pag $Logmsgs.dir ".
    "$Changes $Clientdir ".
    "$Tags.txt $Tags $Tags.db $Tags.pag $Tags.dir ".
    "$Tagfiles.txt $Tagfiles $Tagfiles.db $Tagfiles.pag $Tagfiles.dir ".
    "$Brtags.txt $Brtags.db $Brtags.pag $Brtags.dir ".
    "$Revmap $Revmap.db $Revmap.pag $Revmap.dir $Labels"))
  { die "/bin/rm -rf $Logmsgs ..."; }

use DB_File;
$DBMCLASS="DB_File";

#$myhashinfo = new DB_File::HASHINFO;
#$myhashinfo->{bsize} = 4096;

$myhashinfo = new DB_File::BTREEINFO;

if (! tie(%Files_seen, $DBMCLASS, $Filesseen, O_CREAT|O_RDWR, 0666, $myhashinfo))
  { print "$Myname: can't tie \"$Filesseen\": $!\n"; exit 1; }

if (! tie(%MSGS, $DBMCLASS, $Logmsgs, O_CREAT|O_RDWR, 0666, $myhashinfo))
  { print "$Myname: can't tie \"$Logmsgs\": $!\n"; exit 1; }

if (! open(LABELS, ">$Labels"))
  { print "$Myname: can't open \">$Labels\": $!\n"; exit 1; }

#  The $Tags hash is keyed by the tag name. It's value is set to the
#  branch tag of the branch it belongs to, iff the mapping can be
#  detemermined by observing that a tagged revision is present in
#  exactly one branch, i.e., has moved beyond the branch's branch
#  point, AND is not selected as the base of some other branch.
#
if (! tie(%Tags, $DBMCLASS, $Tags, O_CREAT|O_RDWR, 0666, $myhashinfo))
  { print "$Myname: can't tie \"$Tags\": $!\n"; exit 1; }

#  The Tagfiles hash remembers for each tag mapped by the heuristic,
#  the file where the mapping was established. This is useful in cases
#  where there are conflicts.
#
if (! tie(%Tagfiles, $DBMCLASS, $Tagfiles, O_CREAT|O_RDWR, 0666, $myhashinfo))
  { print "$Myname: can't tie \"$Tagfiles\": $!\n"; exit 1; }

#  The $Brtags hash is keyed by branch tag name, and the value is the
#  actual branch number.
#
if (! tie(%Brtags, $DBMCLASS, $Brtags, O_CREAT|O_RDWR, 0666, $myhashinfo))
  { print "$Myname: can't tie \"$Brtags\": $!\n"; exit 1; }

if (! open(METATMP, ">$Metatmp"))
  { print "$Myname: can't open \">$Metatmp\": $!\n"; exit 1; }

#chdir $CVS_MODULE || die "$Myname: can't chdir \"$CVS_MODULE\": $!";
#$CVS_MODULE = `/bin/pwd`; chop $CVS_MODULE;
#chdir $Here || die "$Myname: can't chdir \"$Here\": $!";

&traverse($CVS_MODULE, 0, "dofile");

close METATMP;
#close REVTAGS;
untie %MSGS;

if (! open(TAGS, ">$Tags.txt"))
  { print "$Myname: can't open \">$Tags.txt\": $!\n"; exit 1; }
foreach $tag (sort(keys(%Tags)))
  { 
    print TAGS "$tag\t";
    if ($Tags{$tag})
      { print TAGS "$Tags{$tag}\n"; }
    else
      { print TAGS "UNMAPPED\n"; }
  }

close TAGS;
print "Wrote $Tags.txt\n";
untie %Tags;
untie %Tagfiles;
&s("rm -f $Tags $Tags.db $Tags.pag $Tags.dir");
&s("rm -f $Tagfiles $Tagfiles.db $Tagfiles.pag $Tagfiles.dir");

if (! open(BRTAGS, ">$Brtags.txt"))
  { print "$Myname: can't open \">$Brtags.txt\": $!\n"; exit 1; }
foreach my $brtag (sort(keys(%Brtags))) { print BRTAGS "$brtag\n"; }
close BRTAGS;
print "Wrote $Brtags.txt\n";
untie %Brtags;
&s("rm -f $Brtags $Brtags.db $Brtags.pag $Brtags.dir");

if ($Prescan) { exit 0; }

sub metasort
{
  my @a = split(/$S/, $a);
  my @b = split(/$S/, $b);

  # The revision time is the primary sort key
  #   - But this is now handled by the external sort; we still
  #     do secondary and tertiary sort keys, below
  #
  #  if ($a[1] != $b[1]) { return $a[1] <=> $b[1]; }

  $a[0] =~ s/^(.*)\///; my $apath = $1;
  $b[0] =~ s/^(.*)\///; my $bpath = $1;

  # Next is the pathname
  #
  if ($apath ne $bpath) { return $apath cmp $bpath; }

  # If we're still tied, it goes to the revision number!
  #
  @aa = split(/\./, $a[0]);
  @bb = split(/\./, $b[0]);

  for (my $i = 0; $i <= $#aa; $i=$i+2)
    {
      if (! defined($bb[$i])) { return 1; }   # a has more positions, thus greater
      if ($aa[$i] < $bb[$i])  { return -1; }  # a is less than b, thus less
      if ($aa[$i] > $bb[$i])  { return 1; }   # and vice-versa

      # if they are equal, we look to the next position:
      #
      if (! defined($aa[$i+1]))
        { die "impossible sort key (RCS rev) \"$a[0]\"?\n"; }
      if (! defined($bb[$i+1]))
        { die "impossible sort key (RCS rev) \"$b[0]\"?\n"; }
      if ($aa[$i+1] < $bb[$i+1])  { return -1; }  # a is less than b, thus less
      if ($aa[$i+1] > $bb[$i+1])  { return 1; }   # and vice-versa

      # Otherwise, we go on to the next level...
    }

  if ($#bb > $#aa) { return -1; }

  die "impossible equal sort keys:\n  <$a>\n  <$b>\n";
}

my $cmd = "sort -n -t $S -k 2 < $Metatmp |";

if (! open(METASORT, $cmd))
  { print "$Myname: can't open \"$cmd\": $!\n"; exit 1; }

if (! open(META, ">$Metadata"))
  { print "$Myname: can't open \">$Metadata\": $!\n"; exit 1; }

# Do the sorting in chunks, per primary sort key. (We're going through
# all of this, BTW, in order to constrain genmetadata's memory
# footprint, which was getting huge when we held all of the tags and
# metadata in-core)
#

my $t = 0;
my @Meta;

while (<METASORT>)
  {
    chomp;
    my @r = split(/$S/, $_);
    if ($r[1] ne $t)
      {
        if ($#Meta >= 0)
          {
            my @Metasorted = sort metasort @Meta;
            foreach my $m (@Metasorted) { print META "$m\n"; }
          }
        $t = $r[1];
        @Meta = ();
      }
    push (@Meta, $_);
  }

if ($#Meta >= 0)
  {
    my @Metasorted = sort metasort @Meta;
    foreach my $m (@Metasorted) { print META "$m\n"; }
  }

close METASORT;
close META;

#if (! open(LABELS, ">$Labels"))
#  { print "$Myname: can't open \">$Labels\": $!\n"; exit 1; }
#
#if (! open(REVTAGS, "sort $Revtags |"))
#  { print "$Myname: can't open \"sort $Revtags |\": $!\n"; exit 1; }
#
#my $curlabel;
#while (<REVTAGS>)
#  {
#    my ($label, $pathrev) = ($_ =~ m/^([^ ]+) (.*)/);
#    if ($label ne $curlabel)
#      {
#        $sublabel = $label;
#        if ($label =~ m/[\#\@]/)
#          {
#            $sublabel =~ s/\#/_hash_/g;
#            $sublabel =~ s/\@/_atsym_/g;
#          }
#        print LABELS "$sublabel\n";
#        $curlabel = $label;
#      }
#    print LABELS "  $pathrev\n";
#  }
#close REVTAGS;
#close LABELS;

#foreach $label (sort(keys(%RCS_Revtags)))
#  {
#    $sublabel = $label;
#    if ($label =~ m/[\#\@]/)
#      {
#        $sublabel =~ s/\#/_hash_/g;
#        $sublabel =~ s/\@/_atsym_/g;
#      }
#    print LABELS "$sublabel\n";
#    foreach $rev (@{$RCS_Revtags{$label}})
#      { print LABELS "  $rev\n"; }
#  }
#close LABELS;

#&s("rm $Revtags");

$Lines  = "$Convdir/lines";
if (! open(LINES, ">$Lines"))
  { print "$Myname: can't open \">$Lines\": $!\n"; }
else
  {
    print       "===== Lines referenced:\n";
    print LINES "===== Lines referenced:\n";
    foreach $line (sort keys %All_lines)
      {
        print       "$line\n";
        print LINES "$line\n";
      }
    close LINES;
  }

exit 0;