<?xml version="1.0"?>
<xsl:stylesheet exclude-result-prefixes="d"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:d="http://docbook.org/ns/docbook"
xmlns:fo="http://www.w3.org/1999/XSL/Format"
version="1.0">
<!-- ********************************************************************
$Id: htmltbl.xsl 9647 2012-10-26 17:42:03Z bobstayton $
********************************************************************
This file is part of the XSL DocBook Stylesheet distribution.
See ../README or http://docbook.sf.net/release/xsl/current/ for
copyright and other information.
******************************************************************** -->
<!-- ==================================================================== -->
<!-- Outputs an fo:table only, not the caption -->
<xsl:template match="d:table|d:informaltable" mode="htmlTable">
<xsl:variable name="numcols">
<xsl:call-template name="widest-html-row">
<xsl:with-param name="rows" select=".//d:tr"/>
</xsl:call-template>
</xsl:variable>
<xsl:variable name="prop-columns"
select=".//d:col[contains(@width, '%')] |
.//d:colgroup[contains(@width, '%')]"/>
<xsl:variable name="table.width">
<xsl:call-template name="table.width"/>
</xsl:variable>
<fo:table xsl:use-attribute-sets="table.table.properties">
<xsl:choose>
<xsl:when test="$fop.extensions != 0 or
$fop1.extensions != 0">
<xsl:attribute name="table-layout">fixed</xsl:attribute>
</xsl:when>
</xsl:choose>
<xsl:attribute name="width">
<xsl:choose>
<xsl:when test="@width">
<xsl:value-of select="@width"/>
</xsl:when>
<xsl:when test="$table.width">
<xsl:value-of select="$table.width"/>
</xsl:when>
<xsl:otherwise>100%</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<xsl:call-template name="table.frame">
<xsl:with-param name="frame">
<xsl:choose>
<xsl:when test="@frame = 'box'">all</xsl:when>
<xsl:when test="@frame = 'border'">all</xsl:when>
<xsl:when test="@frame = 'below'">bottom</xsl:when>
<xsl:when test="@frame = 'above'">top</xsl:when>
<xsl:when test="@frame = 'hsides'">topbot</xsl:when>
<xsl:when test="@frame = 'vsides'">sides</xsl:when>
<xsl:when test="@frame = 'lhs'">lhs</xsl:when>
<xsl:when test="@frame = 'rhs'">rhs</xsl:when>
<xsl:when test="@frame = 'void'">none</xsl:when>
<xsl:when test="@border != '' and @border != 0">all</xsl:when>
<xsl:when test="@border != '' and @border = 0">none</xsl:when>
<xsl:when test="@frame != ''">
<xsl:value-of select="@frame"/>
</xsl:when>
<xsl:when test="$default.table.frame != ''">
<xsl:value-of select="$default.table.frame"/>
</xsl:when>
<xsl:otherwise>all</xsl:otherwise>
</xsl:choose>
</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="make-html-table-columns">
<xsl:with-param name="count" select="$numcols"/>
</xsl:call-template>
<xsl:apply-templates select="d:thead" mode="htmlTable"/>
<xsl:apply-templates select="d:tfoot" mode="htmlTable"/>
<xsl:choose>
<xsl:when test="d:tbody">
<xsl:apply-templates select="d:tbody" mode="htmlTable"/>
</xsl:when>
<xsl:otherwise>
<fo:table-body start-indent="0pt" end-indent="0pt">
<xsl:apply-templates select="d:tr" mode="htmlTable"/>
</fo:table-body>
</xsl:otherwise>
</xsl:choose>
</fo:table>
</xsl:template>
<!-- This template writes rowsep or colsep equivalant for html tables -->
<xsl:template name="html.table.cell.rules">
<xsl:variable name="border"
select="(ancestor::d:table |
ancestor::d:informaltable)[last()]/@border"/>
<xsl:variable name="table.rules"
select="(ancestor::d:table |
ancestor::d:informaltable)[last()]/@rules"/>
<xsl:variable name="rules">
<xsl:choose>
<xsl:when test="$table.rules != ''">
<xsl:value-of select="$table.rules"/>
</xsl:when>
<xsl:when test="$default.table.rules != ''">
<xsl:value-of select="$default.table.rules"/>
</xsl:when>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="$border != '' and $border != 0">
<xsl:attribute name="border">
<xsl:value-of select="$table.cell.border.thickness"/>
<xsl:text> </xsl:text>
<xsl:value-of select="$table.cell.border.style"/>
<xsl:text> </xsl:text>
<xsl:value-of select="$table.cell.border.color"/>
</xsl:attribute>
</xsl:when>
<xsl:when test="$rules = 'none'">
<xsl:attribute name="border-start-style">none</xsl:attribute>
<xsl:attribute name="border-end-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">none</xsl:attribute>
<xsl:attribute name="border-bottom-style">none</xsl:attribute>
</xsl:when>
<xsl:when test="$rules = 'cols' and following-sibling::*">
<!-- If not the last column, add border after -->
<xsl:attribute name="border-start-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">none</xsl:attribute>
<xsl:attribute name="border-bottom-style">none</xsl:attribute>
<xsl:attribute name="border-end-style">
<xsl:value-of select="$table.frame.border.style"/>
</xsl:attribute>
<xsl:attribute name="border-end-width">
<xsl:value-of select="$table.frame.border.thickness"/>
</xsl:attribute>
<xsl:attribute name="border-end-color">
<xsl:value-of select="$table.frame.border.color"/>
</xsl:attribute>
</xsl:when>
<!-- If not the last row, add border below -->
<xsl:when test="$rules = 'rows'">
<xsl:variable name="rowborder">
<xsl:choose>
<!-- If in thead and tbody has rows, add border -->
<xsl:when test="parent::d:tr/parent::d:thead/
following-sibling::d:tbody/d:tr">1</xsl:when>
<!-- If in tbody and tfoot has rows, add border -->
<xsl:when test="parent::d:tr/parent::d:tbody/
following-sibling::d:tfoot/d:tr">1</xsl:when>
<xsl:when test="parent::d:tr/parent::d:tbody/
preceding-sibling::d:tfoot/d:tr">1</xsl:when>
<!-- If following rows, but not rowspan reaches last row -->
<xsl:when test="parent::d:tr/following-sibling::d:tr and
not(@rowspan = count(parent::d:tr/following-sibling::d:tr) + 1)">1</xsl:when>
<xsl:otherwise>0</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:if test="$rowborder = 1">
<xsl:attribute name="border-start-style">none</xsl:attribute>
<xsl:attribute name="border-end-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">none</xsl:attribute>
<xsl:attribute name="border-bottom-style">
<xsl:value-of select="$table.frame.border.style"/>
</xsl:attribute>
<xsl:attribute name="border-bottom-width">
<xsl:value-of select="$table.frame.border.thickness"/>
</xsl:attribute>
<xsl:attribute name="border-bottom-color">
<xsl:value-of select="$table.frame.border.color"/>
</xsl:attribute>
</xsl:if>
</xsl:when>
<xsl:when test="$rules = 'all'">
<xsl:attribute name="border-start-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">none</xsl:attribute>
<xsl:variable name="rowborder">
<xsl:choose>
<!-- If in thead and tbody has rows, add border -->
<xsl:when test="parent::d:tr/parent::d:thead/
following-sibling::d:tbody/d:tr">1</xsl:when>
<!-- If in tbody and tfoot has rows, add border -->
<xsl:when test="parent::d:tr/parent::d:tbody/
following-sibling::d:tfoot/d:tr">1</xsl:when>
<xsl:when test="parent::d:tr/parent::d:tbody/
preceding-sibling::d:tfoot/d:tr">1</xsl:when>
<!-- If following rows, but not rowspan reaches last row -->
<xsl:when test="parent::d:tr/following-sibling::d:tr and
not(@rowspan = count(parent::d:tr/following-sibling::d:tr) + 1)">1</xsl:when>
<xsl:otherwise>0</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:if test="$rowborder = 1">
<xsl:attribute name="border-bottom-style">
<xsl:value-of select="$table.frame.border.style"/>
</xsl:attribute>
<xsl:attribute name="border-bottom-width">
<xsl:value-of select="$table.frame.border.thickness"/>
</xsl:attribute>
<xsl:attribute name="border-bottom-color">
<xsl:value-of select="$table.frame.border.color"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="following-sibling::*">
<!-- If not the last column, add border after -->
<xsl:attribute name="border-end-style">
<xsl:value-of select="$table.frame.border.style"/>
</xsl:attribute>
<xsl:attribute name="border-end-width">
<xsl:value-of select="$table.frame.border.thickness"/>
</xsl:attribute>
<xsl:attribute name="border-end-color">
<xsl:value-of select="$table.frame.border.color"/>
</xsl:attribute>
</xsl:if>
</xsl:when>
<xsl:when test="$rules = 'groups' and ancestor::d:thead
and not(parent::d:tr/following-sibling::d:tr)">
<xsl:attribute name="border-start-style">none</xsl:attribute>
<xsl:attribute name="border-end-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">none</xsl:attribute>
<xsl:attribute name="border-bottom-style">
<xsl:value-of select="$table.frame.border.style"/>
</xsl:attribute>
<xsl:attribute name="border-bottom-width">
<xsl:value-of select="$table.frame.border.thickness"/>
</xsl:attribute>
<xsl:attribute name="border-bottom-color">
<xsl:value-of select="$table.frame.border.color"/>
</xsl:attribute>
</xsl:when>
<xsl:when test="$rules = 'groups' and ancestor::d:tfoot
and not(parent::d:tr/preceding-sibling::d:tr)">
<xsl:attribute name="border-start-style">none</xsl:attribute>
<xsl:attribute name="border-end-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">none</xsl:attribute>
<xsl:attribute name="border-top-style">
<xsl:value-of select="$table.frame.border.style"/>
</xsl:attribute>
<xsl:attribute name="border-top-width">
<xsl:value-of select="$table.frame.border.thickness"/>
</xsl:attribute>
<xsl:attribute name="border-top-color">
<xsl:value-of select="$table.frame.border.color"/>
</xsl:attribute>
</xsl:when>
</xsl:choose>
</xsl:template>
<xsl:template match="d:caption" mode="htmlTable">
<!-- Handled by formal.object.heading -->
</xsl:template>
<xsl:template name="widest-html-row">
<xsl:param name="rows" select="''"/>
<xsl:param name="count" select="0"/>
<xsl:choose>
<xsl:when test="count($rows) = 0">
<xsl:value-of select="$count"/>
</xsl:when>
<xsl:otherwise>
<xsl:choose>
<xsl:when test="$count > count($rows[1]/*)">
<xsl:call-template name="widest-html-row">
<xsl:with-param name="rows" select="$rows[position() > 1]"/>
<xsl:with-param name="count" select="$count"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="widest-html-row">
<xsl:with-param name="rows" select="$rows[position() > 1]"/>
<xsl:with-param name="count" select="count($rows[1]/*)"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="make-html-table-columns">
<xsl:param name="count" select="0"/>
<xsl:param name="number" select="1"/>
<xsl:choose>
<xsl:when test="d:col|d:colgroup/d:col">
<xsl:for-each select="d:col|d:colgroup/d:col">
<fo:table-column>
<xsl:attribute name="column-number">
<xsl:number from="d:table|d:informaltable" level="any" format="1"/>
</xsl:attribute>
<xsl:if test="@width">
<xsl:attribute name="column-width">
<xsl:choose>
<xsl:when test="$fop.extensions != 0 and
contains(@width, '%')">
<xsl:value-of select="concat('proportional-column-width(',
substring-before(@width, '%'),
')')"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="@width"/>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
</xsl:if>
</fo:table-column>
</xsl:for-each>
</xsl:when>
<xsl:when test="$fop.extensions != 0">
<xsl:if test="$number <= $count">
<fo:table-column column-number="{$number}"
column-width="{6.5 div $count}in"/>
<xsl:call-template name="make-html-table-columns">
<xsl:with-param name="count" select="$count"/>
<xsl:with-param name="number" select="$number + 1"/>
</xsl:call-template>
</xsl:if>
</xsl:when>
</xsl:choose>
</xsl:template>
<xsl:template match="d:tbody" mode="htmlTable">
<fo:table-body start-indent="0pt"
end-indent="0pt">
<xsl:apply-templates mode="htmlTable"/>
</fo:table-body>
</xsl:template>
<xsl:template match="d:tfoot" mode="htmlTable">
<fo:table-footer start-indent="0pt"
end-indent="0pt">
<xsl:apply-templates mode="htmlTable"/>
</fo:table-footer>
</xsl:template>
<xsl:template match="d:th|d:td" mode="htmlTable">
<xsl:variable name="bgcolor.pi">
<xsl:call-template name="pi.dbfo_bgcolor"/>
</xsl:variable>
<xsl:variable name="bgcolor">
<xsl:choose>
<xsl:when test="$bgcolor.pi != ''">
<xsl:value-of select="$bgcolor.pi"/>
</xsl:when>
<xsl:when test="string-length(@bgcolor) != 0">
<xsl:value-of select="@bgcolor"/>
</xsl:when>
</xsl:choose>
</xsl:variable>
<xsl:variable name="align">
<xsl:call-template name="inherited.table.attribute">
<xsl:with-param name="entry" select="."/>
<xsl:with-param name="row" select="parent::d:tr"/>
<xsl:with-param name="attribute" select="'align'"/>
</xsl:call-template>
</xsl:variable>
<xsl:variable name="valign">
<xsl:call-template name="inherited.table.attribute">
<xsl:with-param name="entry" select="."/>
<xsl:with-param name="row" select="parent::d:tr"/>
<xsl:with-param name="attribute" select="'valign'"/>
</xsl:call-template>
</xsl:variable>
<fo:table-cell xsl:use-attribute-sets="table.cell.padding">
<xsl:call-template name="table.cell.properties">
<xsl:with-param name="bgcolor.pi" select="$bgcolor"/>
<xsl:with-param name="rowsep.inherit" select="0"/>
<xsl:with-param name="align.inherit" select="$align"/>
<xsl:with-param name="valign.inherit" select="$valign"/>
<xsl:with-param name="colsep.inherit" select="0"/>
</xsl:call-template>
<xsl:if test="@colspan > 1">
<xsl:attribute name="number-columns-spanned">
<xsl:value-of select="@colspan"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="@rowspan > 1">
<xsl:attribute name="number-rows-spanned">
<xsl:value-of select="@rowspan"/>
</xsl:attribute>
</xsl:if>
<fo:block>
<xsl:call-template name="table.cell.block.properties"/>
<xsl:apply-templates/>
</fo:block>
</fo:table-cell>
</xsl:template>
<xsl:template match="d:thead" mode="htmlTable">
<fo:table-header start-indent="0pt"
end-indent="0pt">
<xsl:apply-templates mode="htmlTable"/>
</fo:table-header>
</xsl:template>
<xsl:template match="d:tr" mode="htmlTable">
<fo:table-row>
<xsl:call-template name="table.row.properties"/>
<xsl:apply-templates mode="htmlTable"/>
</fo:table-row>
</xsl:template>
</xsl:stylesheet>
| # | Change | User | Description | Committed | |
|---|---|---|---|---|---|
| #1 | 26953 | Paul Allen | Move //guest/perforce_software/p4convert to //guest/perforce_software/p4convert/main | ||
| //guest/perforce_software/p4convert/docs/docbook-xsl-ns-1.78.1/fo/htmltbl.xsl | |||||
| #2 | 14806 | Paul Allen | Update docs and add +w. | ||
| #1 | 13920 | Paul Allen | copy part 2 (no errors) | ||
| //guest/paul_allen/p4convert-maven/docs/docbook-xsl-ns-1.78.1/fo/htmltbl.xsl | |||||
| #1 | 13895 | Paul Allen | Copying using p4convert-docbook | ||
| //guest/perforce_software/doc_build/main/docbook-xsl-ns-1.78.1/fo/htmltbl.xsl | |||||
| #1 | 12728 | eedwards |
Upgrade ANT doc build infrastructure to assemble PDFs: - remove non-namespaced DocBook source and add namespaced DocBook source. - add Apache FOP 1.1 - copy fonts, images, XSL into _build, establishing new asset structure. The original structure remains until all guides using it can be upgraded, and several other issues can be resolved. - updated build.xml to allow for per-target build properties. - upgraded the P4SAG to use the new infrastructure. - tweaked admonition presentation in PDFs to remove admonition graphics, and resemble closely the presentation used in the new HTML layout, including the same colors. With these changes, building PDFs involves using a shell, navigating into the guide's directory (just P4SAG for now), and executing "ant pdf". Issues still to be resolved: - PDF generation encounters several warnings about missing fonts (bold versions of Symbol and ZapfDingbats), and a couple of locations where the page content exceeds the defined content area. - Due to issues within Apache FOP, PDF generation emits a substantial amount of output that is not easily suppressed without losing important warning information. - Apache FOP's interface to ANT does not expose a way to set the font base directory. The current configuration does work under Mac OSX, but further testing on Windows will need to be done to determine if the relative paths defined continue to work. The workaround is for Windows users to customize the fop-config.xml to provide absolute system paths to the required fonts. - HTML generation needs further browser testing, and exhibits broken navigation on iOS browsers within the TOC sidebar. - A number of PDF and HTML presentation tweaks still need to be made, for example: sidebars, gui* DocBook tags, whitespace, section separation, etc. |
||