ResultForm.Dsr #1

VERSION 5.00
Begin {C62A69F0-16DC-11CE-9E98-00AA00574A4F} ResultForm 
   BorderStyle     =   3  'Fixed Dialog
   Caption         =   "ResultForm"
   ClientHeight    =   5910
   ClientLeft      =   45
   ClientTop       =   435
   ClientWidth     =   7725
   ControlBox      =   0   'False
   MaxButton       =   0   'False
   MinButton       =   0   'False
   OleObjectBlob   =   "ResultForm.dsx":0000
   ShowInTaskbar   =   0   'False
   StartUpPosition =   1  'CenterOwner
End
Attribute VB_Name = "ResultForm"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit

Private m_Listbox As ListBoxCopy
Private m_ConfirmDisplay As Boolean
Private m_port As String

Private Sub cmdClose_Click()
    On Error GoTo Error_Block
    Dim t As Tracker: Set t = GStackTrace.Enter(TypeName(Me), "cmdClose_Click")
    Dim p4 As P4COM.p4
    
    Set p4 = NewP4
    If m_ConfirmDisplay Then
        RegOptions.DisplayConfirmations = (HideDialog.Value = 0)
    End If
    If HideConnectionWarning.Value Then
        g_p4interface.SaveConnectionWarning p4.port
    End If
    Unload Me
    Exit Sub

Error_Block:
    t.Report

End Sub

Public Sub DisplayResult(Title As String, FilePath As String, Result As Long, _
                  InfoArr() As String, ErrorArr() As String, _
                  Optional ConfirmDialog As Boolean = False)

    Dim t As Tracker: Set t = GStackTrace.Enter(TypeName(Me), "DisplayResult")
    Dim p4 As P4COM.p4
    
    Set p4 = NewP4
    ResultForm.Caption = Title
    If Len(FilePath) <> 0 Then
        FileName = FilePath
    Else
        FileName.Visible = False
        FilenameLabel.Visible = False
    End If
    ResultBox.Clear

    If Result <> 0 Then
        AddToListBox Me, ResultBox, "*** Error ***"
        ' Assume that other errors will be documented by return value
        If IsEmptyArray(InfoArr) And IsEmptyArray(ErrorArr) Then
            AddToListBox Me, ResultBox, "Error communicating with Perforce server (" & p4.port & ")"
            AddToListBox Me, ResultBox, "Please check that the Perforce server is"
            AddToListBox Me, ResultBox, "running, and check your environment settings"
            AddToListBox Me, ResultBox, "(P4PORT, P4CLIENT, P4CONFIG, etc.)."
            If Not g_p4interface.HideConnectionWarning(p4.port) Then
                HideConnectionWarning.Visible = True
            End If
        End If
    End If

    DisplayArray InfoArr, Me, ResultBox
    DisplayArray ErrorArr, Me, ResultBox

    If ConfirmDialog Then
        m_ConfirmDisplay = True
    Else
        HideDialog.Visible = False
        cmdClose.Top = cmdClose.Top - HideDialog.Height
        HideConnectionWarning.Top = HideConnectionWarning.Top - HideDialog.Height
        Me.Height = Me.Height - HideDialog.Height
    End If

    Screen.MousePointer = vbDefault
    SetParent2 Me, g_p4interface.App.Caption
    Me.Show vbModal
    Unload Me

End Sub

Private Sub InitForm()
    Dim t As Tracker: Set t = GStackTrace.Enter(TypeName(Me), "InitForm")
    
    Set m_Listbox = New ListBoxCopy
    m_Listbox.Initialize Me, ResultBox
    m_ConfirmDisplay = False

End Sub

Private Sub UserForm_Initialize()
    ' Allow right click menu for copying to clipboard
    On Error GoTo Error_Block
    Dim t As Tracker: Set t = GStackTrace.Enter(TypeName(Me), "UserForm_Initialize")

    InitForm
    Exit Sub

Error_Block:
    t.Report
End Sub