download_p4api.bat #5

@echo off

pushd "%~dp0"

if exist p4d rd /s /q p4d
mkdir p4d

set FTPFILE="%CD%\ftp.script"
rem build the ftp script file
echo bin>%FTPFILE%

echo cd perforce/r09.1/bin.ntx64/>>%FTPFILE%
echo get p4api_vs2005_dyn.zip>>%FTPFILE%
echo !ren p4api_vs2005_dyn.zip p4api_vs2005_dyn_x64.zip>>%FTPFILE%

echo cd ../bin.ntx86/>>%FTPFILE%
echo get p4api_vs2003_dyn.zip>>%FTPFILE%
echo get p4api_vs2005_dyn.zip>>%FTPFILE%
echo get p4api_vs2005_dyn_vsdebug.zip>>%FTPFILE%

echo cd ../../>>%FTPFILE%

call :fetch_p4d 09.1
call :fetch_p4d 08.2
call :fetch_p4d 08.1
call :fetch_p4d 07.3
call :fetch_p4d 07.2
call :fetch_p4d 07.1
call :fetch_p4d 06.2
call :fetch_p4d 06.1
call :fetch_p4d 05.2


echo quit>>%FTPFILE%


ftp -A -s:%FTPFILE% ftp.perforce.com

if exist p4api_vs2003_dyn rd /s /q p4api_vs2003_dyn
if exist p4api_vs2005_dyn rd /s /q p4api_vs2005_dyn
if exist p4api_vs2005_dyn_vsdebug rd /s /q p4api_vs2005_dyn_vsdebug
if exist p4api_vs2005_dyn_x64 rd /s /q p4api_vs2005_dyn_x64


.\unxutils\unzip p4api_vs2003_dyn.zip
move p4api-*-vs2003_dyn p4api_vs2003_dyn

.\unxutils\unzip p4api_vs2005_dyn.zip
move p4api-*-vs2005_dyn p4api_vs2005_dyn

.\unxutils\unzip p4api_vs2005_dyn_vsdebug.zip
move p4api-*-vs2005_dyn_vsdebug p4api_vs2005_dyn_vsdebug

.\unxutils\unzip p4api_vs2005_dyn_x64.zip
move p4api-*-vs2005_dyn p4api_vs2005_dyn_x64

rem cleanup
if exist p4api_vs2005_dyn_x64.zip del /q p4api_vs2005_dyn_x64.zip
if exist p4api_vs2005_dyn.zip del /q p4api_vs2005_dyn.zip
if exist p4api_vs2003_dyn.zip del /q p4api_vs2003_dyn.zip
if exist p4api_vs2005_dyn_vsdebug.zip del /q p4api_vs2005_dyn_vsdebug.zip

del /q %FTPFILE%

popd

goto :eof

:fetch_p4d
    echo !mkdir p4d\%~1>>%FTPFILE%
    echo lcd p4d/%~1>>%FTPFILE%
    echo get r%~1/bin.ntx86/p4d.exe>>%FTPFILE%
    echo lcd ..\..>>%FTPFILE%
goto :eof